Arduino使用PWM驱动TB6612控制直流减速电机

发布时间：2024年01月04日

一、PWM介绍

二、硬件介绍

1、设备型号

一、PWM介绍

前面有见过使用PWM控制呼吸灯的实验：Arduino-多种模式下IO输入读取和输出控制-CSDN博客

（三、LED呼吸灯控制）

PWM引脚说明

二、硬件介绍

1、设备型号

单片机：Arduino MEGA 2560

电机驱动芯片：TB6612

电机：JGB-520直流减速电机

TB6612电机驱动芯片

JGB-520直流减速电机

系统整体接线图

2、接线图

电机、驱动芯片、控制器接线说明。数字表示接单片机的引脚。

3、TB6612控制电机转动逻辑

（1）控制逻辑

（2）真值表

4、G37系列JGB-520直流减速电机

JGB-520直流减速电机，减速比为1:30。

测速码盘模组是一款使用霍尔传感器编码器的测速模块，配有13线强磁码盘，AB双相输出共同利用下，通过计算可得出末端轮子转一圈，脉冲数为30*13*2=780。如果使用单相脉冲数为30*13*1=390。

三、测试程序

1、电机正反转控制

代码

int STBY = 8; //使能端
  
//Motor A
int PWMA = 9; //左电机PWM输出控制脚   
int AIN1 = 7; //左电机正极  
int AIN2 = 6; //左电机负极  
  
//Motor B  
int PWMB = 10; //右电机PWM输出控制脚
int BIN1 = 13; //右电机正极 
int BIN2 = 12; //右电机负极  
  
void setup(){  
  pinMode(STBY, OUTPUT);  
  
  pinMode(PWMA, OUTPUT);  
  pinMode(AIN1, OUTPUT);  
  pinMode(AIN2, OUTPUT);  
  
  pinMode(PWMB, OUTPUT);  
  pinMode(BIN1, OUTPUT);  
  pinMode(BIN2, OUTPUT);  
}  

void runset(int motor, int speed, int direction){  
  
  digitalWrite(STBY, HIGH); //使能驱动模块脚 
  
  boolean Pin1 = LOW;  
  boolean Pin2 = HIGH;  
  
  if(direction == 1){  
    Pin1 = HIGH;  
    Pin2 = LOW;  
  }  
  
  if(motor == 1){  
    digitalWrite(AIN1, Pin1);  
    digitalWrite(AIN2, Pin2);  
    analogWrite(PWMA, speed);  
  }else{  
    digitalWrite(BIN1, Pin1);  
    digitalWrite(BIN2, Pin2);  
    analogWrite(PWMB, speed);  
  }  
}  
  
void loop(){  
  runset(1, 255, 1); //左电机全速向前转  
  runset(2, 255, 1); //右电机全速向前转  
  
  delay(1000); //1秒 
  stop(); //停转
  delay(250); //两轮继续向前转  
  
  runset(1, 128, 0); //左电机半速向后转  
  runset(2, 128, 0); //右电机半速向后转  
  
  delay(1000);  
  stop();  
  delay(250);  
}  
   
void stop(){  
  digitalWrite(STBY, LOW);   
}

2、编码器脉冲读取

（1）方式1

①实现方式

1）对1#电机编码器脉冲读取

2）使用一个中断外部输入中断方式，读取脉冲数量。

3）编码器A、B相接单片机两个引脚，判断两个引脚信号，来计算脉冲。

②代码

读取的编码器脉冲累计数量保存，使用long型。long保存的最大值2^32=4294967296


//
const long _1000msTime = 1000;    // 1000 milli seconds
unsigned long _1000msLastTime;
const long _100msTime = 100;      // 100 milli seconds
unsigned long _100msLastTime; 
const long _10msTime = 10;        // 10 milli seconds
unsigned long _10msLastTime;


//编码器引脚定义-1#电机
#define APin 3  //Encoder的A相引脚
#define BPin 2  //Encoder的B相引脚

volatile long PulsCount=0;          //脉冲累计数量
volatile long PulsSpeed=0;          //当前每秒脉冲数


//电机控制
int STBY = 8; //使能端  
//Motor A
int PWMA = 9; //左电机PWM输出控制脚   
int AIN1 = 7; //左电机正极  
int AIN2 = 6; //左电机负极    
//Motor B  
int PWMB = 10; //右电机PWM输出控制脚
int BIN1 = 13; //右电机正极 
int BIN2 = 12; //右电机负极  


void setup() 
{
  Serial.begin(9600);
  //
  pinMode(STBY, OUTPUT);    
  pinMode(PWMA, OUTPUT);  
  pinMode(AIN1, OUTPUT);  
  pinMode(AIN2, OUTPUT);    
  pinMode(PWMB, OUTPUT);  
  pinMode(BIN1, OUTPUT);  
  pinMode(BIN2, OUTPUT); 
  //设置编码器引脚为输入
  pinMode(APin, INPUT_PULLUP);
  pinMode(BPin, INPUT_PULLUP);
  //为引脚添加中断函数  
  attachInterrupt(digitalPinToInterrupt(APin),Encoder_Count,CHANGE);    //当电平发生改变时触发中断函数--------------------两个引脚都要接  
  /*================中断函数说明============================
   *attachInterrupt(中断引脚,中断函数,CHANGE)
   *LOW：      当引脚为低电平时触发中断服务程序
   *CHANGE：   当引脚电平发生变化时触发中断服务程序
   *RISING：   当引脚电平由低电平变为高电平时触发中断服务程序
   *FALLING：  当引脚电平由高电平变为低电平时触发中断服务程序
   *=======================================================
  */

}

void loop() 
{  
  runset(1, 64, 1);   //左电机半速向后转  
  runset(2, 64, 0);   //右电机半速向后转  
  //
  TimeProc();

  //interrupts();     //中断启用
  //noInterrupts();   //中断禁用
}

void TimeProc()
{
  //1000ms执行一次
  if ((millis() - _1000msLastTime) >= _1000msTime)
  {
    _1000msLastTime = millis( );    
    //累计脉冲数量
    Serial.print("Encoder Accumulate puls is:");
    Serial.println(PulsCount); 
    //每秒钟脉冲数量->390个脉冲转一圈
    Serial.print("Encoder speed puls is:");
    Serial.println(PulsSpeed);     
    PulsSpeed=0;
  }
  //100ms执行一次
  if ((millis() - _100msLastTime) >= _100msTime)
  {
    _100msLastTime = millis( );   
    //
     
  }
  //10ms执行一次
  if ((millis() - _10msLastTime) >= _10msTime)
  {
    _10msLastTime = millis( );  
    //
        
  } 
}


//定义中断函数 ——编码器计数函数
void Encoder_Count()
{
  int a=digitalRead(APin);    //将高低电平转化为int型数值
  int b=digitalRead(BPin);
  //a为上升沿的时 b为1   或者a为下降沿时   b为0
  if(a==b)  
  {
    PulsCount++;                  //顺时针转动
    PulsSpeed++;
  }
  else
  {
    //a为上升沿的时 b为0   或者a为下降沿时   b为1
    PulsCount--;                      //逆时针转动
    PulsSpeed--;  
  }
}

void runset(int motor, int speed, int direction)
{    
  digitalWrite(STBY, HIGH); //使能驱动模块脚   
  boolean Pin1 = LOW;  
  boolean Pin2 = HIGH;    
  if(direction == 1)
  {  
    Pin1 = HIGH;  
    Pin2 = LOW;  
  }    
  if(motor == 1)
  {  
    digitalWrite(AIN1, Pin1);  
    digitalWrite(AIN2, Pin2);  
    analogWrite(PWMA, speed);  
  }
  else
  {  
    digitalWrite(BIN1, Pin1);  
    digitalWrite(BIN2, Pin2);  
    analogWrite(PWMB, speed);  
  }  
}  

void stop()
{  
  digitalWrite(STBY, LOW);   
}

③测试

累计脉冲数量、每秒钟脉冲数量读取如下：

（2）方式2

①实现方式

1）对1#电机、2#电机编码器脉冲读取

2）使用两个个中断外部输入中断方式，读取脉冲数量。

3）两个电机编码器A相分别接单片机两个引脚，判断引脚信号，来计算脉冲。

4)确定电机旋转方向，正转时候读取的编码器脉冲值自加、反转的时候读取的编码器脉冲值自减。

②代码


//
const long _1000msTime = 1000;    // 1000 milli seconds
unsigned long _1000msLastTime;
const long _100msTime = 100;      // 100 milli seconds
unsigned long _100msLastTime; 
const long _10msTime = 10;        // 10 milli seconds
unsigned long _10msLastTime;


//初始编码器引脚定义与计数定义 全局变量
#define APin 3  //1#电机-Encoder的A相引脚
#define BPin 2  //2#电机-Encoder的A相引脚

volatile long count=0;//定义计数变量


//电机控制
int STBY = 8; //使能端  
//Motor A
int PWMA = 9; //左电机PWM输出控制脚   
int AIN1 = 7; //左电机正极  
int AIN2 = 6; //左电机负极    
//Motor B  
int PWMB = 10; //右电机PWM输出控制脚
int BIN1 = 13; //右电机正极 
int BIN2 = 12; //右电机负极  

//1#电机脉冲
volatile long PulsCount_Motor1=0;          //脉冲累计数量
long PulsSpeed_Motor1=0;                   //当前每秒脉冲数
//2#电机脉冲
volatile long PulsCount_Motor2=0;          //脉冲累计数量
long PulsSpeed_Motor2=0;                   //当前每秒脉冲数

//电机旋转方向
int motor1_Dir=1;         //定义1为正转，0为反转
int motor2_Dir=1;

void setup() 
{
  Serial.begin(9600);
  //
  pinMode(STBY, OUTPUT);    
  pinMode(PWMA, OUTPUT);  
  pinMode(AIN1, OUTPUT);  
  pinMode(AIN2, OUTPUT);    
  pinMode(PWMB, OUTPUT);  
  pinMode(BIN1, OUTPUT);  
  pinMode(BIN2, OUTPUT); 
  //设置编码器引脚为输入
  pinMode(APin, INPUT_PULLUP);
  pinMode(BPin, INPUT_PULLUP);
  //为引脚添加中断函数  
  //attachInterrupt(digitalPinToInterrupt(APin),incrementCount,RISING);   //当电平发生改变时触发中断函数-----------接1个引脚
  
  attachInterrupt(digitalPinToInterrupt(APin),Encoder1_Count,CHANGE);    //当电平发生改变时触发中断函数-----------接1个引脚
  attachInterrupt(digitalPinToInterrupt(BPin),Encoder2_Count,CHANGE);    //当电平发生改变时触发中断函数-----------接1个引脚  
  /*================中断函数说明============================
   *attachInterrupt(中断引脚,中断函数,CHANGE)
   *LOW：      当引脚为低电平时触发中断服务程序
   *CHANGE：   当引脚电平发生变化时触发中断服务程序
   *RISING：   当引脚电平由低电平变为高电平时触发中断服务程序
   *FALLING：  当引脚电平由高电平变为低电平时触发中断服务程序
   *=======================================================
  */

}

void loop() 
{
  motor1_Dir=1;  
  motor2_Dir=0;
  runset(1, 64, motor1_Dir); //左电机正转  
  runset(2, 64, motor2_Dir); //右电机反转  
  //
  TimeProc();
}

void TimeProc()
{
  //1000ms执行一次
  if ((millis() - _1000msLastTime) >= _1000msTime)
  {
    _1000msLastTime = millis( );    
    //1#电机编码器脉冲反馈
    Serial.print("Motor1 pules is:");
    Serial.print(PulsCount_Motor1); 
    Serial.print("  ; ");
    Serial.print("Encoder speed puls is:");
    Serial.println(PulsSpeed_Motor1);     
    PulsSpeed_Motor1=0;

    //2#电机编码器脉冲反馈
    Serial.print("Motor2 pules is:");
    Serial.print(PulsCount_Motor2); 
    Serial.print("  ; ");
    Serial.print("Encoder speed puls is:");
    Serial.println(PulsSpeed_Motor2);     
    PulsSpeed_Motor2=0;
  }
  //100ms执行一次
  if ((millis() - _100msLastTime) >= _100msTime)
  {
    _100msLastTime = millis( );   
    //
     
  }
  //10ms执行一次
  if ((millis() - _10msLastTime) >= _10msTime)
  {
    _10msLastTime = millis( );  
    
  }
 
}

void Encoder1_Count() 
{
  if(motor1_Dir==1)
  {
    PulsCount_Motor1++;     
    PulsSpeed_Motor1++;
  }
  else
  {
    PulsCount_Motor1--;     
    PulsSpeed_Motor1--;
  }
}

void Encoder2_Count() 
{  
  if(motor2_Dir==1)
  {
    PulsCount_Motor2++;     
    PulsSpeed_Motor2++;
  }
  else
  {
    PulsCount_Motor2--;     
    PulsSpeed_Motor2--;
  }
}

void runset(int motor, int speed, int direction)
{    
  digitalWrite(STBY, HIGH); //使能驱动模块脚   
  boolean Pin1 = LOW;  
  boolean Pin2 = HIGH;    
  if(direction == 1)
  {  
    Pin1 = HIGH;  
    Pin2 = LOW;  
  }    
  if(motor == 1)
  {  
    digitalWrite(AIN1, Pin1);  
    digitalWrite(AIN2, Pin2);  
    analogWrite(PWMA, speed);  
  }
  else
  {  
    digitalWrite(BIN1, Pin1);  
    digitalWrite(BIN2, Pin2);  
    analogWrite(PWMB, speed);  
  }  
}  

void stop()
{  
  digitalWrite(STBY, LOW);   
}

③测试

3、减速电机转速计算

①如下图所示，得到每秒钟的编码器脉冲数量。②减速电机末端轴转一圈脉冲是390。

则计算减速电机末端每秒钟旋转的圈数：

旋转速度=Encoder speed puls/390。

如图圈出来的：电机1转速：941/390=2.1428转/秒、电机2转速：-893/390=-2.2897转/秒

文章来源:https://blog.csdn.net/panjinliang066333/article/details/135367084
本文来自互联网用户投稿，该文观点仅代表作者本人，不代表本站立场。本站仅提供信息存储空间服务，不拥有所有权，不承担相关法律责任。如若内容造成侵权/违法违规/事实不符，请联系我的编程经验分享网邮箱：chenni525@qq.com进行投诉反馈，一经查实，立即删除！