通达信阿隆指标(Aroon)选股公式，判断新趋势的开始和衡量趋势的强度

阿隆指标(Aroon)由图莎尔·钱德(Tushar Chande)发明的，用于判断新趋势的开始和衡量趋势的强度，和一般的震荡指标不同，阿隆指标关注的是价格相对于时间的变化。Aroon在梵语中的意思是“黎明的第一缕光”，从指标发明者的取名也可以看出指标的用途。

Aroon指标由上轨和下轨两条线组成，都是基于一个周期数（通常是25个交易日）来计算的，当然周期数可以根据自己的需求调整。

上轨 = (25 - 25日高点距离当前的周期数)?÷?25 x 100

下轨 = (25 - 25日低点距离当前的周期数)?÷?25 x 100

阿隆指标的波动范围是0-100。上轨超过70表明强劲的上升趋势，下轨高于 70 表明强劲的下降趋势。上轨低于50表明上升趋势正在减弱，下轨低于50表明下降趋势减弱。

一、阿隆Aroon指标的原理

阿隆指标的原理其实很简单，根据公式，当创25日新高时，25日高点距离当前的周期数就是0，这样计算出的上轨值就等于100。如果25日高点出现在10 天前，上轨的值为( 25 - 10 ) ÷?25 x 100 = 60。类似的，创25日新低，下轨的值就是100。

把下面的创25日新高、创25新低K线变色指标公式加载到主图，对比一下副图阿隆指标，就明白了。

XG:=H=HHV(H,25);

XD:=L=LLV(L,25);

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLORYELLOW;

STICKLINE(XD,H,L,0,1),COLORGREEN;

STICKLINE(XD,C,O,3,0),COLORGREEN;

二、阿隆Aroon指标公式副图

通达信自带阿隆指标公式，在K线图界面输入“AROON”就可以加载到副图，但是公式中下轨公式是错的，应该是用LLVBARS(L,N)。

经过修改的阿隆指标公式如下：

N:=25;

上轨:(N-HHVBARS(H,N))/N*100,COLORRED;

下轨:(N-LLVBARS(L,N))/N*100,COLORGREEN;

NOTEXT1:70,DOTLINE,COLORMAGENTA;

NOTEXT2:50,DOTLINE,COLORYELLOW;

NOTEXT3:30,DOTLINE,COLORBLUE;

三、阿隆指标公式主图

思路：阿隆指标上轨在70以上持续一段时间，向下突破50之后再次站上50。

N:=25;

UP:=(N-HHVBARS(H,N))/N*100;

DN:=(N-LLVBARS(L,N))/N*100;

SZ:=EVERY(UP>70,20);

T:=BARSLAST(SZ);

JC:=CROSS(UP,50);

XG:=JC AND COUNT(JC,T)=1 AND C>O AND (C-L)/(H-L)>0.6;

MA5:MA(C,5);

MA10:MA(C,10);

MA20:MA(C,20);

MA60:MA(C,60);

STICKLINE(XG,H,L,0,1),COLORYELLOW;

STICKLINE(XG,C,O,3,0),COLOR117777;

STICKLINE(XG,C,O,2.5,0),COLOR119999;

STICKLINE(XG,C,O,2,0),COLOR11BBBB;

STICKLINE(XG,C,O,1.5,0),COLOR11DDDD;

STICKLINE(XG,C,O,1,0),COLOR44FFFF;

DRAWICON(XG,L,11);

四、阿隆指标选股公式

N:=25;

UP:=(N-HHVBARS(H,N))/N*100;

DN:=(N-LLVBARS(L,N))/N*100;

SZ:=EVERY(UP>70,20);

T:=BARSLAST(SZ);

JC:=CROSS(UP,50);

XG:JC AND COUNT(JC,T)=1 AND C>O AND (C-L)/(H-L)>0.6;

关注技术Pie，学习更多通达信指标公式编写知识。版权所有，转载请注明出处。

友情提醒：本文仅供学习交流技术指标公式，不构成任何投资建议。投资有风险，入市需谨慎。