QT学习_19_基于NSIS脚本的软件安装包制作随笔

在以前的QT学习_16_制作软件安装包-CSDN博客这篇博客中已经讲过一些相关的内容了，本文的内容会更深入一些，主要解决以下几个问题：

1. 软件安装之后，软件却没有软件安装目录的文件读写权限，以前我们是强行让用户把软件安装到D盘，但是如果有些用户没有D盘呢？所以以前的解决方式并不是很好，本文将解决这个问题。
2. 软件运行时内部会调用子程序，而这些子程序的运行是需要运行环境的，因此需要添加系统环境变量。
3. 第2步添加完环境变量后，系统未必会即可生效（亲测会有延迟），因此要尽量让用户安装完软件后，重启电脑，否则直接运行软件会出现问题。
4. 作为一个专业的软件，卸载的时候也不能马虎，如果卸载的时候，软件正在运行，卸载程序在删除某些文件的时候就会遇到阻碍，最终会导致卸载不干净，有残留。 因此卸载的时候要判断软件是否在运行，如在运行则需把软件强行关闭，再继续卸载。 另外，与软件相关的环境变量也要删除，保证不留任何的痕迹。

1 制作软件安装包的软件

虽然以前已经说过了，我们用的是“易量安装”这一款制作软件安装包的软件，但是这里还是贴一下链接：?易量安装软件安装包V2.1.1资源-CSDN文库

2 本文所提功能需要用到的插件

在解决第1条和第4条问题的时候，会分别用到一个.dll文件， 这两个.dll，把它拷贝到......\ELiang\NSIS\Plugins里面即可。估计其他类似的软件安装包制作软件，也是...\NSIS\Plugins。这个就自己去摸索了。在基于NSIS制作软件安装包时需要用到的两个插件资源-CSDN文库

3 nsis脚本分享

前面所提到的4个问题，我不会一个一个细讲，下面我将直接贴出我的nsis脚本，其中重点关注注释。

;Mr. Miracle：

看一看奇迹先生说了什么?。

; 该脚本使用 易量安装(az.eliang.com) 向导生成
; 安装程序初始定义常量
!define PRODUCT_NAME "Whisper"
!define PRODUCT_VERSION "1.0.0.1"
!define PRODUCT_PUBLISHER "Mr. Miracle"
!define PRODUCT_WEB_SITE ""
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"

SetCompressor lzma

; 提升安装程序权限(vista,win7,win8)
RequestExecutionLevel admin

Name "${PRODUCT_NAME} ${PRODUCT_VERSION}"
OutFile "setup.exe"
;ELiangID 统计编号     /*  安装统计项名称：【Whisper】  */
LoadLanguageFile "${NSISDIR}\Contrib\Language files\SimpChinese.nlf"
InstallDir "$PROGRAMFILES\Whisper"
Icon "D:\WhisperInstallerMaker\whisper.ico"
UninstallIcon "D:\WhisperInstallerMaker\whisper.ico"
InstallDirRegKey HKLM "${PRODUCT_UNINST_KEY}" "UninstallString"
DirText "安装程序将安装 $(^Name) 在下列文件夹。$\r$\n$\r$\n要安装在不同文件夹，单击“浏览”并选择其他文件夹。"
ShowInstDetails show
ShowUninstDetails show
BrandingText " "

;安装包版本号格式必须为x.x.x.x的4组整数,每组整数范围0~65535,如:2.0.1.2
;若使用易量统计,版本号将用于区分不同版本的安装情况,此时建议用户务必填写正确的版本号
;!define INSTALL_VERSION "2.0.1.2"

;VIProductVersion "${INSTALL_VERSION}"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "ProductName"      "Whisper"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "Comments"         "Whisper(Mr. Miracle)"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "CompanyName"      "Mr. Miracle"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "LegalCopyright"   "Mr. Miracle()"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "FileDescription"  "Whisper"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "ProductVersion"   "${INSTALL_VERSION}"
;VIAddVersionKey /LANG=${LANG_SimpChinese} "FileVersion"      "${INSTALL_VERSION}"

Section "MainSection" SEC01
  SetOutPath "$INSTDIR"
  ; Mr. Miracle：无论你选什么文件夹作为安装目录，用户对这个文件夹都具有可读可写权限，可规避应用程序需要读写文件带来的文件权限问题
  AccessControl::GrantOnFile \
  "$INSTDIR" "(BU)" "GenericRead + GenericWrite"
  Pop $0

  File /r "D:\WhisperInstallerMaker\Whisper\*.*"
  ; Mr. Miracle：在桌面创建一个快捷方式
  CreateShortCut "$DESKTOP\Whisper.lnk" "$INSTDIR\Whisper.exe"
SectionEnd

Section -AdditionalIcons
  CreateShortCut "$SMPROGRAMS\Whisper\卸载Whisper.lnk" "$INSTDIR\uninst.exe"
SectionEnd

Section -Post
  WriteUninstaller "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayName" "$(^Name)"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "UninstallString" "$INSTDIR\uninst.exe"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "DisplayVersion" "${PRODUCT_VERSION}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "URLInfoAbout" "${PRODUCT_WEB_SITE}"
  WriteRegStr ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}" "Publisher" "${PRODUCT_PUBLISHER}"
  ;Mr. Miracle：添加应用程序添加需要使用的环境变量
  ReadRegStr $0 HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
  WriteRegExpandStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path" "$0;$INSTDIR\environment\runtime\win64"
  SendMessage ${HWND_BROADCAST} ${WM_WININICHANGE} 0 "STR:Environment" /TIMEOUT=500
  ;Mr. Miracle：让用户尽量重启电脑让环境变量生效
  MessageBox MB_YESNO|MB_ICONQUESTION "是否重启电脑使$(^Name)的配置生效，否则$(^Name)的运行可能将不正常？" IDNO +2
  Reboot

SectionEnd

/******************************
*  以下是安装程序的卸载部分  *
******************************/

!include "WordFunc.nsh" ;Mr. Miracle：删除环境变量需要包含的
Section Uninstall
  Delete "$INSTDIR\uninst.exe"

  Delete "$SMPROGRAMS\Whisper\卸载Whisper.lnk"
  Delete "$DESKTOP\Whisper.lnk" ;Mr. Miracle：卸载后删除桌面快捷方式

  RMDir "$SMPROGRAMS\Whisper"

  RMDir /r "$INSTDIR\fittool"
  RMDir /r "$INSTDIR\frdata"
  RMDir /r "$INSTDIR\iconengines"
  RMDir /r "$INSTDIR\imageformats"
  RMDir /r "$INSTDIR\platforms"
  RMDir /r "$INSTDIR\styles"
  RMDir /r "$INSTDIR\translations"
  RMDir /r "$INSTDIR\xml"

  RMDir /r "$INSTDIR"   ;Mr. Miracle：卸载完成后将安装目录全部删除

  DeleteRegKey ${PRODUCT_UNINST_ROOT_KEY} "${PRODUCT_UNINST_KEY}"

  ;Mr. Miracle：删除应用程序的所添加的环境变量
  ReadRegStr $R0 HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path"
  ${WordReplace} $R0 ";$INSTDIR\v94\runtime\win64" "" "+" $R1
  WriteRegExpandStr HKLM "SYSTEM\CurrentControlSet\Control\Session Manager\Environment" "Path" "$R1"
SectionEnd

/* 根据 NSIS 脚本编辑规则,所有 Function 区段必须放置在 Section 区段之后编写,以避免安装程序出现未可预知的问题. */

Function un.onInit
  MessageBox MB_ICONQUESTION|MB_YESNO|MB_DEFBUTTON2 "卸载将丢失软件内所有数据，请您确认是否做好备份。您确定要继续卸载$(^Name)？" IDYES +2
  Abort

  ;Mr. Miracle：检测在卸载时候，软件是否正在运行
  nsProcess::_FindProcess "Whisper.exe"
  Pop $R0
  IntCmp $R0 0 running no_running no_running
  running:
  MessageBox MB_ICONQUESTION|MB_YESNO "卸载程序检测到 ${PRODUCT_NAME} 正在运行，是否强行关闭并继续卸载?" IDYES dokill IDNO stopit
  no_running:
  GoTo endding
  dokill:
  nsProcess::_CloseProcess "Whisper.exe"
  Pop $R0
  GoTo endding
  stopit:
  Abort
  endding:
  nsProcess::_Unload
FunctionEnd

Function un.onUninstSuccess
FunctionEnd

这篇博客多少有点子敷衍，不过细心的朋友肯定会有所获的，?最后愿我们共同进步！ 感谢您的阅读，欢迎留言讨论、收藏、点赞、分享。?